3D World 76/3DWI76.iso/pc/Tutorials.dir/00019_Script_QuickTime Control Button

Text File | 2006-02-08 | 6KB | 190 lines

-- QuickTime CONTROL BUTTON
-- DProvides standard functionality for custom buttons
-- used to control Quicktime video sprites
-- v1 - 14 October   1998 by Darrel Plant
--       3 February  2000 Added isOKToAttach and resolve handlers. Removed
--                         redundant error checking. Added new mErrorAlert
--                         handler from James Newton. - Karl Miller

on getBehaviorDescription
  return \
    "QT CONTROL BUTTON" & RETURN & RETURN & \
    "Use this behavior to make almost any sprite into a control button for Quicktime video sprites. " & \
    "Standard controls available through this behavior are Play, Stop/Pause, Rewind to beginning, Jump to End, Fast Forward (2x) and Fast backward (2x). " & \
    "Drag behavior onto a sprite, select the Quicktime sprite to control, and which action the button will perform." & RETURN & RETURN & \
    "PARAMETERS:" & RETURN & \
    " - which Quicktime video sprite to control" & RETURN & \
    " - Button action (rewind, stop, play, end, backward, forward)" & RETURN & RETURN & \
    "PERMITTED TYPES:" & RETURN & \
    " - Quicktime video to control" & RETURN & \
    " - any graphics sprite(s) for the controls"
end getBehaviorDescription

on getBehaviorTooltip
  return \
    "Create custom QuickTime sprite video control buttons. " & \
    "First place the QuickTime sprite on stage, then attach the behavior to the sprites that will serve as the controls."
end getBehaviorTooltip

--PROPERTIES --

property pSprite                   -- button sprite reference
property pActive                   -- activity flag for buttons
property alertFlag                 -- set to the ticks when the alert is shown so that
                                   --   the alert doesn't appear twice in succession

-- user-defined properties
property pAction                   -- button sprite action
property pVideoSprite              -- video sprite reference

-- EVENT HANDLERS --

on beginSprite me
  pAction = resolve(pAction)
  mInitialize me
end beginSprite

on resolve (prop)
  case prop of
    pAction:
      choicesList = ["Rewind", "Stop", "Play", "End", "Backward", "Forward"]
      lookup = [#rewind, #stop, #play, #end, #backward, #forward]
  end case
  return lookup[findPos(choicesList, prop)]
end resolve

on mouseDown me
  mVideoButton me
end mouseDown

on mouseUp me
  -- most button actions for the controls occur on mouseDown
  -- but the fast-forward actions are deactivated when the mouse
  -- is released
  case pAction of
    #backward, #forward: mVideoButton me
  end case
end mouseUp

on mouseLeave me
  -- test performed in case mouse rolls off of fast
  -- forward/backward button
  case pAction of
    #backward, #forward: mVideoButton me
  end case
end mouseLeave

-- CUSTOM HANDLERS --

on mInitialize me
  -- set reference for button sprite
  pSprite = sprite (me.spriteNum)
  pActive = FALSE
end mInitialize

on mVideoButton me
  -- test to see if sprite is still video
  if mVerifyVideo (pVideoSprite) then
    -- determine button action and act accordingly
    case pAction of
        -- start sprite playing
      #play:
        sprite (pVideoSprite).movieRate = 1
        -- stop sprite playing
      #stop:
        sprite (pVideoSprite).movieRate = 0
        -- stop play and rewind sprite to beginning
      #rewind:
        sprite (pVideoSprite).movieRate = 0
        sprite (pVideoSprite).movieTime = 0
        -- stop play and wind sprite to end of video
      #end:
        sprite (pVideoSprite).movieRate = 0
        sprite (pVideoSprite).movieTime = \
          sprite (pVideoSprite).member.duration
        -- test mouseDown, if down, play movie backward at
        -- double speed
      #backward:
        if the mouseDown and rollover (me.spriteNum) then
          pActive = TRUE
          sprite (pVideoSprite).movieRate = -2
        else
          if pActive then sprite (pVideoSprite).movieRate = 0
          pActive = FALSE
        end if
        -- test mouseDown, if down, play movie forward at
        -- double speed
      #forward:
        if the mouseDown and rollover (me.spriteNum) then
          pActive = TRUE
          sprite (pVideoSprite).movieRate = 2
        else
          if pActive then sprite (pVideoSprite).movieRate = 0
          pActive = FALSE
        end if
    end case
  end if
end mVideoButton

on mVerifyVideo vSpriteNum
  -- tests sprite chennel and returns TRUE if sprite uses
  -- Quicktime cast member
  return sprite (vSpriteNum).member.type = #QuickTimeMedia
end mVerifyVideo

on mVideoSpriteList
  -- builds list of valid video sprites for property
  -- description list handler
  -- initialize video list
  vVideoList = []
  -- test all channels in movie
  repeat with i = 1 to the lastChannel
    -- test to see if there's a video in the channel
    if mVerifyVideo (i) then
      -- add video channels to list
      add vVideoList, i
    end if
  end repeat
  return vVideoList
end mVideoSpriteList

on mErrorAlert me
  if the ticks - alertFlag > 10 then
    alert "No video sprites are currently on the Stage."
    alertFlag = the ticks
  end if
end mErrorAlert


-- AUTHOR-DEFINED PARAMETERS --

on isOKToAttach (me, aSpriteType, aSpriteNum)
  return aSpriteType = #graphic
end isOKToAttach


on getPropertyDescriptionList me
  if not the currentSpriteNum then
    -- behavior has been attached to script channel
    exit
  end if
  -- build video sprite list
  vVideos = mVideoSpriteList ()
  if not vVideos.count then
    -- call error regarding no video sprites
    return mErrorAlert (me)
  else
    vPDList = [:]
    setaProp vPDList, #pVideoSprite, [#comment: "Video sprite channel", \
      #format: #string, #default: vVideos[1], #range: vVideos]
    setaProp vPDList, #pAction, \
    [\
    #comment: "Video button action", \
      #format: #string, \
      #default: "Play", \
      #range: ["Rewind", "Stop", "Play", "End", "Backward", "Forward"] \
]
    return vPDList
  end if
end getPropertyDescriptionList